home *** CD-ROM | disk | FTP | other *** search
/ SGI Hot Mix 17 / Hot Mix 17.iso / HM17_SGI / research / lib / read_gif.pro < prev    next >
Text File  |  1997-07-08  |  6KB  |  230 lines
  1. ; $Id: read_gif.pro,v 1.8 1997/03/12 20:52:36 stevep Exp $
  2. ;
  3. ; Copyright (c) 1992-1997, Research Systems, Inc.  All rights reserved.
  4. ;       Unauthorized reproduction prohibited.
  5.  
  6. ;
  7. ;  GifReadByte
  8. ;    Read a single byte out of the given file
  9. ;
  10. FUNCTION GifReadByte, unit
  11.     ch    = 0b
  12.     READU, unit, ch
  13.     RETURN, ch
  14. END
  15.  
  16. PRO READ_GIF, FILE, IMAGE, R, G, B, MULTIPLE=mult, CLOSE=close
  17. ;
  18. ;+
  19. ; NAME:
  20. ;    READ_GIF
  21. ;
  22. ; PURPOSE:
  23. ;    Read the contents of a GIF format image file and return the image
  24. ;    and color table vectors (if present) in the form of IDL variables.
  25. ;
  26. ; CATEGORY:
  27. ;    Input/Output.
  28. ;
  29. ; CALLING SEQUENCE:
  30. ;    READ_GIF, File, Image [, R, G, B]
  31. ;
  32. ; INPUTS:
  33. ;    File:    Scalar string giving the name of the rasterfile to read
  34. ;
  35. ; Keyword Inputs:
  36. ;    CLOSE = if set, closes any open file and returns if the MULTIPLE images
  37. ;        per file mode was used.  This keyword is used
  38. ;        without additional parameters.
  39. ;    
  40. ;    MULTIPLE = if set, read files containing multiple images per
  41. ;        file.  Each call to READ_GIF returns the next image,
  42. ;        with the file remaining open between calls.  The File
  43. ;        parameter is ignored after the first call.  Reading
  44. ;        past the last image returns a scalar value of -1 in IMAGE, and
  45. ;        closes the file.  When reading the 2nd and subsequent
  46. ;        images, R, G, and B are not returned.
  47. ;
  48. ; OUTPUTS:
  49. ;    Image:    The 2D byte array to contain the image.
  50. ;
  51. ;
  52. ; OPTIONAL OUTPUT PARAMETERS:
  53. ;     R, G, B:    The variables to contain the Red, Green, and Blue color vectors
  54. ;        if the rasterfile containes colormaps.
  55. ;
  56. ; SIDE EFFECTS:
  57. ;    None.
  58. ;
  59. ; COMMON BLOCKS:
  60. ;    READ_GIF_COMMON.
  61. ; RESTRICTIONS:
  62. ;    This routine only reads in the first image in a file (the format
  63. ;    allows many). Local colormaps are not supported.
  64. ;    Only 8 bit images are supported.
  65. ;
  66. ;    The Graphics Interchange Format(c) is the Copyright property
  67. ;    of CompuServ Incorporated.  GIF(sm) is a Service Mark property of
  68. ;    CompuServ Incorporated. 
  69. ;
  70. ; EXAMPLE:
  71. ;    To open and read the GIF image file named "foo.gif" in the current
  72. ;    directory, store the image in the variable IMAGE1, and store the color
  73. ;    vectors in the variables R, G, and B, enter:
  74. ;
  75. ;        READ_GIF, "foo.gif", IMAGE1, R, G, B
  76. ;
  77. ;    To load the new color table and display the image, enter:
  78. ;
  79. ;        TVLCT, R, G, B
  80. ;        TV, IMAGE1
  81. ; 
  82. ; MODIFICATION HISTORY:
  83. ;    Written June 1992, JWG
  84. ;    Added GIF89a and interlaced format, Jan, 1995, DMS.
  85. ;    Added MULTIPLE and CLOSE, Aug, 1996.
  86. ;    
  87. ;-
  88. ; Copyright (c) 1992-1996, Research Systems, Inc.  All rights reserved.
  89. ;    Unauthorized reproduction prohibited.
  90. ;
  91.  
  92. ;    Define GIF header (and screen descriptor)
  93.  
  94. COMMON READ_GIF_COMMON, unit, width, height
  95.  
  96. if n_elements(unit) eq 0 then unit = -1
  97.  
  98.  
  99. on_error, 2        ;Return to caller on errors
  100. image  = -1        ;No image read yet
  101.  
  102. if keyword_set(close) then begin
  103.     if unit gt 0 then FREE_LUN, unit
  104.     unit = -1
  105.     return
  106.     endif
  107.  
  108. h    = {     magic:bytarr(6),                $
  109.         width_lo:0b, width_hi:0b,            $
  110.         height_lo:0b, height_hi:0b,            $
  111.         screen_info:0b, background:0b, reserved:0b }
  112.  
  113. ;    Image header declaration
  114.  
  115. ihdr    = {     left:0, top:0,            $    ; we read this but
  116.         iwidth:0, iheight:0,        $    ; mostly we ignore
  117.         image_info:0b }                ; its content
  118.  
  119. if keyword_set(mult) and unit gt 0 then goto, next_image
  120. if unit gt 0 then free_lun, unit
  121.  
  122. OPENR, unit, file, /GET_LUN, /BLOCK, ERROR=i
  123. if i ne 0 then message, 'Error occured opening file: '+file+'.'
  124.  
  125. READU, unit, h        ;Read gif header
  126.  
  127. ;    Check Magic in header: GIF87a or GIF89a.
  128. gif    = STRING(h.magic[0:2])
  129. vers = STRING(h.magic[3:5])
  130.  
  131. IF gif NE 'GIF' THEN BEGIN
  132.     FREE_LUN, unit
  133.     unit = -1
  134.     MESSAGE, 'File ' + file + ' is not a GIF file.'
  135. ENDIF
  136.  
  137. IF vers ne '87a' and vers ne '89a' then $
  138.     MESSAGE, /INFO, 'GIF Version incompatible:'+vers+'.'
  139.  
  140. width    = h.width_hi * 256 + h.width_lo
  141. height    = h.height_hi * 256 + h.height_lo
  142.  
  143. ;    Find out how big the color map is
  144.  
  145. bits_per_pixel    = (h.screen_info AND 'F'X) + 1
  146. color_map_size    = 2 ^ bits_per_pixel
  147.  
  148. ;    Read in the colormap (optional)
  149.  
  150. IF (h.screen_info AND '80'X) NE 0 THEN BEGIN
  151.     map    = BYTARR(3,color_map_size, /NOZERO)
  152.     READU, unit, map
  153.     map    = transpose(map)
  154.     r    = map[*,0]
  155.     g    = map[*,1]
  156.     b    = map[*,2]
  157.     ENDIF
  158.  
  159.  
  160. ;    Read the image description
  161.  
  162. next_image:  while 1 do begin        ;Read till we get a terminator
  163.   cmd = GifReadByte(unit)        ;Loop thru commands in file.
  164.   CASE STRING(cmd) OF
  165.  
  166. ';':    BEGIN                ; GIF trailer (0x3b)
  167.     FREE_LUN, unit
  168.     unit = -1
  169.     return
  170.     ENDCASE
  171.  
  172. ',':    BEGIN                ; Image description (0x2c)
  173.     READU,unit,ihdr
  174.  
  175.     ; Check for file formats we don't support
  176.     ; We don't support local colormaps
  177.  
  178.     if (ihdr.image_info AND '80'X) NE 0 THEN begin  ;Local color map
  179.        lcolor_map_size = 2^((ihdr.image_info and 7) + 1)
  180.        junk = bytarr(3, lcolor_map_size, /NOZERO)
  181.        readu, unit, junk
  182.        message,'Local colormaps ignored.', /CONTINUE
  183.        endif
  184.  
  185.     ;    Allocate an array to hold the image
  186.     image    = BYTARR(width, height, /NOZERO)
  187.  
  188.     ;    Now call special GIF-LZW routine hidden within IDL
  189.     ;    to do the ugly serial bit stream decoding
  190.  
  191.     DECODE_GIF,unit,image        ; magic
  192. ;        This should be the 0 byte that ends the series:
  193.     dummy = GifReadByte(unit)    ;Loop thru commands in file.
  194.     if dummy ne 0 then message,/info,'No trailing 0.'
  195.  
  196.     ;    Reorder rows in an interlaced image
  197.  
  198.     if (ihdr.image_info AND '40'X) NE 0 THEN BEGIN
  199.         l = lindgen(height)    ;Row indices...
  200.             ;Giff interlace ordering
  201.         p = [l[where(l mod 8 eq 0)], l[where(l mod 8 eq 4)], $
  202.          l[where(l mod 4 eq 2)], l[where(l and 1)]]
  203.         image2 = bytarr(width, height, /NOZERO)
  204.         h1 = height-1
  205.         for i=0, h1 do image2[0, h1-p[i]] = image[*,h1-i]
  206.         image = temporary(image2)
  207.     ENDIF
  208.     if keyword_set(mult) then return    ;Leave file open
  209.         FREE_LUN, unit
  210.         unit = -1
  211.         RETURN
  212.     ENDCASE
  213.  
  214. '!':    BEGIN                ;Gif Extention block (ignored) (0x21)
  215.     label = GifReadByte(unit)    ;toss extension block label
  216.     repeat begin            ;read and ignore blkss
  217.       blk_size = GifReadByte(unit)    ;block size
  218.       if blk_size ne 0 then begin
  219.         junk = BYTARR(blk_size, /NOZERO)
  220.         READU, unit, junk
  221.         endif
  222.     endrep until blk_size eq 0
  223.     ENDCASE
  224.  
  225. ELSE:    message,'Unknown GIF keyword in ' + file + string(cmd, format='(2x,Z2)')
  226. ENDCASE
  227. endwhile
  228.  
  229. END
  230.